Aminet 30/Aminet 30 (1999)(Schatztruhe)[!][Apr 1999].iso/Aminet/game/patch/WHDIGamesH-M.lzh/games/JetSetWilly2.lha/JSW2Install/Install_JSW2

Text File | 1998-02-21 | 5KB | 254 lines

;
;$VER: Jet Set Willy II HD Installer script v2.00 (c) 1997-98 John Girvin
;

(welcome "Welcome to the Jet Set Willy II Hard Drive Installer")
(set @app-name "Jet Set Willy II HD")
(set #JROOTDIR "DH0:")
(set #JDESTDIR #JROOTDIR)
(set #JDATDIR  #JROOTDIR)
(set #JDEFTRAINERS 4)
(set #JUSEGUI 0)
(set #JSTARTGLASSES 162)

(if    (<> @user-level 2)
    (abort "You must select 'Expert' user level")
)

(if    (< @installer-version 2818051)
    (abort "This package requires at least version 43.3 of the Installer program")
)

(message "\n\nWelcome to the Jet Set Willy II Hard Drive Installer\n"
         "(c) 1997-98 John Girvin\n\n"
         "Please read the documentation thoroughly before"
         " attempting to use this installer!\n\n"
         "This is version 2.00\n\n"
         "Click 'Proceed' to begin."
)


;
; Generate names of installation directories
;
(set #JROOTDIR
    (askdir
        (prompt "Where would you like Jet Set Willy II installed?\n"
                "(a new drawer called 'Jet_Set_Willy_II' will be created here)"
        )
        (help @askdir-help)
        (default #JROOTDIR)
    )
)
(set #JDESTDIR (tackon #JROOTDIR "Jet_Set_Willy_II/"))
(set #JDATDIR (tackon #JDESTDIR "data/"))
(set @default-dest #JDESTDIR)
(set @execute-dir #JDESTDIR)


(set #JUSEGUI
    (askchoice
        (prompt "Do you want the cheat GUI to appear every time you load Jet Set Willy II?\n"
                "(this may be changed later by editing the tooltypes of the 'Jet_Set_Willy_II' program)"
        )
        (help @askchoice-help)
        (choices "Yes" "No")
        (default #JUSEGUI)
    )
)


(set #JDEFTRAINERS
    (askoptions
        (prompt "Please select the default options to use:\n"
                "(these may be changed later by either"
                " editing the tooltypes of the 'Jet_Set_Willy_II'"
                " program or using the cheat GUI)"
        )
        (help @askoptions-help)
        (choices "Infinite lives" "Invulnerability" "Use saved game")
        (default #JDEFTRAINERS)
    )
)


(set #JSTARTGLASSES
    (asknumber
        (prompt "Please enter the default number of glasses"
                " left to be collected at the start of each game:\n"
                "(this may be changed later by either"
                " editing the tooltypes of the 'Jet_Set_Willy_II'"
                " program or using the cheat GUI)"
        )
        (help @asknumber-help)
        (range 0 162)
        (default #JSTARTGLASSES)
    )
)

;
; Create installation directories
;
(makedir #JDESTDIR
    (prompt "I will now create the directory '" #JDESTDIR "'")
    (help @makedir-help)
    (infos)
    (confirm)
)

(makedir #JDATDIR
    (prompt "I will now create the directory '" #JDATDIR "'")
    (help @makedir-help)
    (confirm)
)


;
; Copy WHDload and extractor slave to destination
;
(copyfiles
    (prompt "Copying WHDLoad program")
    (help @copyfiles-help)
    (source "WHDLoad")
    (dest #JDESTDIR)
    (nogauge)
    (noposition)
    (optional fail force)
)

(copyfiles
    (prompt "Copying data extractor slave")
    (help @copyfiles-help)
    (source "JSWMakeDat")
    (dest #JDESTDIR)
    (nogauge)
    (noposition)
    (optional fail force)
)

;
; Create data files from game disk
;
(message "\n\n\nPlease insert your Jet Set Willy II game disk in drive DF0:\n\n"
            "*** WARNING ***\n\n"
            "Multitasking will be disabled while the game files"
            " are being created. After inserting the disk, please"
            " ensure that all disk and network activity has finished"
            " before clicking 'Proceed'.\n\n"
            "Click 'Proceed' when ready."
)


(working
    (cat "Creating game data files in '" #JDATDIR "'\n\n"
            "*** Multitasking is disabled. DON`T PANIC! ***"
    )
)


(run (cat (tackon #JDESTDIR
                  "WHDLoad SLAVE=JSWMakeDat NOVBRMOVE NOCACHE NOAUTOVEC NOTRAPHANDLER"
          )
     )
)


;
; Did the data extractor work?
; Check that the last file was created
;
(if (<>    (getsize (tackon #JDATDIR "mansion")) 10216)
    (abort "Could not create data files !")
)

;
; Delete extractor slave
;
(delete
    (tackon #JDESTDIR "JSWMakeDat")
    (optional force)
)

;
; Copy HD drawer icon
;
(copyfiles
    (prompt "Copying HD drawer icon")
    (help @copyfiles-help)
    (source "Drawer.inf")
    (newname "Jet_Set_Willy_II.info")
    (dest #JROOTDIR)
    (nogauge)
    (optional fail force)
)


;
; Copy HD loading bits
;
(copyfiles
    (prompt "Copying trainer GUI program")
    (help @copyfiles-help)
    (source "Jet_Set_Willy_II")
    (dest #JDESTDIR)
    (nogauge)
    (optional fail force)
)

(copyfiles
    (prompt "Copying trainer GUI program icon")
    (help @copyfiles-help)
    (source "GUI.inf")
    (newname "Jet_Set_Willy_II.info")
    (dest #JDESTDIR)
    (nogauge)
    (optional fail force)
)

(tooltype
    (prompt "Setting trainer program icon tooltypes")
    (dest (tackon #JDESTDIR "Jet_Set_Willy_II"))
    (settooltype "GLASSES" (cat #JSTARTGLASSES))
)

(if (= #JUSEGUI 1)
    (tooltype
        (prompt "Setting trainer program icon tooltypes")
        (dest (tackon #JDESTDIR "Jet_Set_Willy_II"))
        (settooltype "NOGUI" "")
    )
)

(if (<> 0 (IN #JDEFTRAINERS 0))
    (tooltype
        (prompt "Setting trainer program icon tooltypes")
        (dest (tackon #JDESTDIR "Jet_Set_Willy_II"))
        (settooltype "INF_LIVES" "")
    )
)

(if (<> 0 (IN #JDEFTRAINERS 1))
    (tooltype
        (prompt "Setting trainer program icon tooltypes")
        (dest (tackon #JDESTDIR "Jet_Set_Willy_II"))
        (settooltype "INVULNERABLE" "")
    )
)

(if (<> 0 (IN #JDEFTRAINERS 2))
    (tooltype
        (prompt "Setting trainer program icon tooltypes")
        (dest (tackon #JDESTDIR "Jet_Set_Willy_II"))
        (settooltype "USESAVE" "")
    )
)

(copyfiles
    (prompt "Copying HD loader slave")
    (help @copyfiles-help)
    (source "JSW2HD")
    (dest #JDESTDIR)
    (nogauge)
    (optional fail force)
)